re set filter to

Réponse acceptée !
>>>je trouve pourtant que c'est bien pratique et rapide pour les débutants !

A ton choix, mais je crois que les débutants qui apprennent à programmer, devraient apprendre de la bonne facon, la plus efficace et la plus sécure. Surtout si un jour tu écrit une applicatiion qui va aller sur un serveur, avec 200 utilisateurs avec une table à filtrer de 100,000 records, ton client va se plaindre tres vite de la lenteur de ton application.  Qunad tu allais (ou va encore) apprendre à l'école, et le prof te dit 'voici comment faire' est-ce que tu décide de faire à ta facon parce ce que c'est 'pratique et rapide'? Je dois espérer que non. Voici un example de la facon de faire que j'utilse dans mes applications.
1. Crée un simple formulaire.
2. Ajoute un grille (fait rian avec pour l'instant autre que la déposer sur le formulaire.
3. Dans le dataenvironment met un table (par example pour le cas de notre excercise met la table 'customer' que se trouve probablement dans ton dossier HOME(2)+'\tastrade\data'.
4. Met le buffering de la table (cursor) à 5. Qui est bon pour les applications à plusieurs utilisateurs.
5. Ajoute un bouton sur la forme pour sauvegarder les records.
6. Dans l'init de la forme met ceci:

Thisform.grid1.RecordSource =''  && preserver le format de la grille et clairer les records
Select * From customer Where country ="Mexico" Into Cursor moncurseur Readwrite && Faire un select pour les clients qui demeurent au Mexique
CURSORSETPROP("Buffering",5,"moncurseur") && Changer le buffering du curseur
With This.grid1 
    .ColumnCount = 2  && Mettre le nombre de colonnes à la grille
    .RecordSource="moncurseur"  && Mettre le recordsource vers le curseur
    .Column1.header1.Caption = "Société"  && Le titre de la colonne 1
    .Column1.ControlSource ="moncurseur.company_name"  && Assigner le champs
    .Column1.Width = 200  && Ajuster la largeur
    .Column2.ControlSource ="moncurseur.COUNTRY"  && Assigner la colonne 2
    .Column2.header1.Caption = "Pays"  && Titre de la colonne 2
Endwith

En faisant comme ci-haut, c'est vite et sécure et tu peux changer tout ce que tu veux sans déranger les autres utilisateurs puisque tu est en mode curseur.
Pour ce que est de sauvgarder, la c'est peut-etre un peu plus compliqué comme technique, mais une fois compris, tu reviendra jamais en arriere. Voci le code du click du bouton sauvegarde:

LOCAL Array monarray[1]  && Créer un tableau pour compter les champs
LOCAL x  && Variable juste pour l'exemple
x = 0   && Initialise à 0
Select moncurseur  && Selectionner le curseur
nFieldCount=Afields(monarray,'Moncurseur')  && Compter combien de champs on doit vérifier
Scan
    For i = 1 To nFieldCount  && Faire un loop pour voir si on a un champs quio a changé de valeur
        If Getfldstate(monarray[i,1]) > 1  && Si la valeur est plus haute que 1 c'est que le champs a été modifié on doit suavegarder le records au complet
                ** ce champs a changé on doit le sauvegarder dans la table principale
              x = x + 1  && On compte combien de records on sauvegarde
            Scatter Name oRecord  && On se crée un objet que contient toute les valeurs du record
            Select customer  && On va a la table principale
            Set Order To customer_i  && On change l'index
            If Seek(oRecord.customer_id)  && On cherche le records
               if  Getfldstate(monarray[i,1]) = 2  && record supprimé
                 DELETE
               else
                Gather name oRecord  && Un fois trouvé on replace tous les valeurs avec la valeurs de l'objet
               endif
               Loop  && et on sort de la loop, puisqu'on vient de sauvegarder et on passe au prochain
            Endif
        Endif
    Endfor
ENDSCAN
=TABLEUPDATE(.t.,.t.,'customer')  && On fait un mis a jour de la table principale
MESSAGEBOX("Il y a "+TRANSFORM(x)+" champs qui ont changé")  && A titre d'exemple on montre combien de records on été sauvegardés

Tout cela pour te dire que moi aussi j'ai commencé avec SET FILTER, mais on réalise tres vite qu'il y a de meilleur facons, plus rapide et plus sécure.


Mike Gagnon