Quelle technique veux-tu utilser ? les vues ou bien SQL Pass-through?
Pour les vues, il te faut créer un database. Dans ce database, tu ne crées pas de table, mais une connexion à ton serveur SQL (l'assistant va très bien pour ça dans un premier temps). Ensuite (toujours avec l'assistant), tu crées dans ce database tes vues sur les tables de ta base de donnée SQL. Ces vues "contiennent" la requète SQL (le query), et portent un nom que tu vas utiliser exactement comme si c'était une table :
use mon_dbc!ma_vue alias toto in 0
select toto
scan
...<tout ce que tu veux>...
endscan
par sécurité (par exemple si tu utilises une identification user dans SQL, et que tu ne veux pas stocker de pw dans ton dbc fox), tu peux utilser une autre connexion que celle qui est définie dans ton dbc avec USE ma_vue CONNSTRING...
Avec SQL Pass-through, les choses sont une peu plus compliquées à écrire, parce que tu vas stocker ta requète dans une chaine de caractère, que tu vas "passer" à ton serveur SQL par la commande SQLEXEC ; ton serveur SQL va exécuter cette requète et te retourne le résultat dans un curseur dont le nom est le 3ème paramètre de la commande SQLEXEC. Tu fais ce que tu veux ensuite sur ce curseur..
Quelques exemples tirés de l'aide deVFP9:
******************
CLEAR
LOCAL lnConn
LOCAL lnPercent AS Int && Input parameters must be typed.
LOCAL lnOutput
lnPercent = 50
lnOutput = 0
* Make connection, assuming a local trusted connection.
lnConn = SQLCONNECT('local')
IF m.lnConn > 0 && Success.
* Set the active database to PUBS.
SQLEXEC(m.lnConn, 'use pubs')
* Execute SELECT statement.
SQLEXEC(m.lnConn, 'SELECT * FROM authors', 'PubAuthors')
BROWSE
* Execute INSERT statement, get value of identity field.
SQLEXEC(m.lnConn, "INSERT INTO JOBS (job_desc, min_lvl, max_lvl);
VALUES ('Developer',75,150)")
SQLEXEC(m.lnConn, "SELECT SCOPE_IDENTITY()", "job_id")
? "ID for added Job is " + LTRIM(STR(job_id.exp))
* Execute DELETE statement. Get number of records affected.
SQLEXEC(m.lnConn, "DELETE FROM JOBS WHERE job_desc ='Developer'")
SQLEXEC(m.lnConn, "SELECT @@ROWCOUNT", 'rowcount')
? rowcount.exp, "record(s) deleted"
* Call a stored procedure with no parameters.
SQLEXEC(m.lnConn, 'sp_who', 'activeusers')
BROWSE
* Execute stored procedure with an INPUT parameter.
SQLEXEC(m.lnConn, 'exec byroyalty ?lnPercent','HalfOffAuthors')
* Create temp stored procedure with OUTPUT parameter and call it.
SQLEXEC(m.lnConn, "CREATE PROCEDURE #MyProc @outparam int OUTPUT AS;
SELECT @outparam=100")
SQLEXEC(m.lnConn, "exec #myProc ?@lnOutput")
? m.lnOutput
* Create a temp stored procedure with INPUT and OUTPUT parameters
* and call it.
SQLEXEC(m.lnConn, "CREATE PROCEDURE #MyProc2 " + ;
"@inputparam INT, " + ;
"@outparam int OUTPUT " + ;
"AS SET @outparam=@inputparam*10")
SQLEXEC(m.lnConn, "exec #myProc2 ?lnPercent, ?@lnOutput")
? m.lnOutput
* Get version information.
SQLEXEC(m.lnConn, 'SELECT @@VERSION','SQLVersion1')
? STRTRAN(SQLVersion1.Exp,CHR(0))
* Disconnect.
SQLDISCONNECT(m.lnConn)
ELSE
? "Unable to connect to SQL Server"
ENDIF
RETURN
*********************
Il existe un excellent livre sur la question "Taming Visual FoxPro'SQL" que l'association AtoutFox vient de traduire en français. Tu le trouveras ici: http://www.hentzenwerke.com
ATTENTION AU LOOP DANS LE SCAN ! ça n'est pas une faute de syntaxe, mais je ne suis pas certain que tu en aies vraiment besoin (tu veux vraiment réexécuter tes instructions sur le même enregistrement??)